◆ Purpose

to swap tokens

◆ Input & Return value

(uint amount0Out, uint amount1Out, address to, bytes calldata data) ⇒ none

◆ Example

amount0Out(WETH) = 1000 amount1Out(USDC) = 974721890337 to(my address) = 0xED98485593D5865E892f823e1f66FB99fE64F639 data = “” or “encode(BORROW_TOKEN_ADDRESS,AMOUNT_OF_BORROW_TOKEN)

“” ⇒ normal swap, “encode(X,Y) ⇒ Flash swap

◆ Code and Explain

This code is a little difficult

require(balance0Adjusted.mul(balance1Adjusted) >= uint(_reserve0).mul(_reserve1).mul(1000**2), 'UniswapV2: K');

(balance0Adjusted).mul(balance1Adjusted) = newK ⇒ K after executing this swap

(_reserve0).mul(_reserve1).mul(1000**2) = oldK ⇒ K before executing before swap

👉 If newK is smaller than oldK(newK < oldK), this K value approaching 0. This code works to save this problem👏👏👏

function swap(uint amount0Out, uint amount1Out, address to, bytes calldata data) external lock {
        require(amount0Out > 0 || amount1Out > 0, 'UniswapV2: INSUFFICIENT_OUTPUT_AMOUNT');
        (uint112 _reserve0, uint112 _reserve1,) = getReserves(); // gas savings
        require(amount0Out < _reserve0 && amount1Out < _reserve1, 'UniswapV2: INSUFFICIENT_LIQUIDITY');

        uint balance0;
        uint balance1;
        { // scope for _token{0,1}, avoids stack too deep errors
        address _token0 = token0;
        address _token1 = token1;
        require(to != _token0 && to != _token1, 'UniswapV2: INVALID_TO');
        if (amount0Out > 0) _safeTransfer(_token0, to, amount0Out); // optimistically transfer tokens
        if (amount1Out > 0) _safeTransfer(_token1, to, amount1Out); // optimistically transfer tokens
        if (data.length > 0) IUniswapV2Callee(to).uniswapV2Call(msg.sender, amount0Out, amount1Out, data);
        balance0 = IERC20(_token0).balanceOf(address(this));
        balance1 = IERC20(_token1).balanceOf(address(this));
        }
        uint amount0In = balance0 > _reserve0 - amount0Out ? balance0 - (_reserve0 - amount0Out) : 0;
        uint amount1In = balance1 > _reserve1 - amount1Out ? balance1 - (_reserve1 - amount1Out) : 0;
        require(amount0In > 0 || amount1In > 0, 'UniswapV2: INSUFFICIENT_INPUT_AMOUNT');
        { // scope for reserve{0,1}Adjusted, avoids stack too deep errors
        uint balance0Adjusted = balance0.mul(1000).sub(amount0In.mul(3)); //  997 
        uint balance1Adjusted = balance1.mul(1000).sub(amount1In.mul(3));
        require(balance0Adjusted.mul(balance1Adjusted) >= uint(_reserve0).mul(_reserve1).mul(1000**2), 'UniswapV2: K');
        }

        _update(balance0, balance1, _reserve0, _reserve1);
        emit Swap(msg.sender, amount0In, amount1In, amount0Out, amount1Out, to);
    }

◆ Resources

• Github

https://github.com/Uniswap/v2-core/blob/master/contracts/UniswapV2Pair.sol#L159